쉼표로 구분된 항목을 새 행으로 분할

쉼표로 구분된 항목을 새 행으로 분할

닫혔습니다. 이 질문은 다음과 같습니다.디버깅 세부 정보.현재 답변을 수락하고 있지 않습니다.

---

원하는 동작, 특정 문제 또는 오류, 문제를 재현하는 데 필요한 최단 코드를 포함하도록 질문을 편집합니다.이것은 다른 사람들이 질문에 대답하는 데 도움이 될 것입니다.

8년 전에 문을 닫았습니다.

이 질문을 개선합니다.

나는 현재 이 데이터를 시트에 가지고 있습니다.

Col A   Col B
1       angry birds, gaming
2       nirvana,rock,band

두 번째 열에 쉼표로 구분된 항목을 분할하고 아래와 같은 새 행에 삽입합니다.

Col A   Col B
1   angry birds
1   gaming
2   nirvana
2   rock
2   band

나는 이것이 VBA로 할 수 있다고 확신하지만 내 스스로는 그것을 알아낼 수 없었습니다.

셀 루프보다는 변형 배열을 사용하는 것이 좋습니다. 일단 데이터 세트가 의미가 있으면 코드를 더 빨리 파악할 수 있습니다.코드가 더 길어도 :)

아래 샘플은 원본 데이터를 볼 수 있도록 C열과 D열에 덤프합니다.바꾸다[c1].Resize(lngCnt, 2).Value2 = Application.Transpose(Y)로.[a1].Resize(lngCnt, 2).Value2 = Application.Transpose(Y)원본 데이터를 덤프하다

[regexp로 업데이트되어 다음 이후 빈칸 제거,i ", band"가 "band"가 됨]

Sub SliceNDice() 
Dim objRegex As Object 
Dim X 
Dim Y 
Dim lngRow As Long 
Dim lngCnt As Long 
Dim tempArr() As String 
Dim strArr 
Set objRegex = CreateObject("vbscript.regexp") 
objRegex.Pattern = "^\s+(.+?)$" 
 'Define the range to be analysed
X = Range([a1], Cells(Rows.Count, "b").End(xlUp)).Value2 
Redim Y(1 To 2, 1 To 1000) 
For lngRow = 1 To UBound(X, 1) 
     'Split each string by ","
    tempArr = Split(X(lngRow, 2), ",") 
    For Each strArr In tempArr 
        lngCnt = lngCnt + 1 
         'Add another 1000 records to resorted array every 1000 records
        If lngCnt Mod 1000 = 0 Then Redim Preserve Y(1 To 2, 1 To lngCnt + 1000) 
        Y(1, lngCnt) = X(lngRow, 1) 
        Y(2, lngCnt) = objRegex.Replace(strArr, "$1") 
    Next 
Next lngRow 
 'Dump the re-ordered range to columns C:D
[c1].Resize(lngCnt, 2).Value2 = Application.Transpose(Y) 
End Sub 

데이터를 A 열에 가져오고 결과를 C 열에 넣습니다.

Sub SplitAll()
    Dim src As Range
    Dim result As Variant
    For Each src In Range("A:A").SpecialCells(xlCellTypeConstants)
        result = Split(src, ",")
        'last cell in column C
        With Cells(Rows.Count, 3).End(xlUp)
            Range(.Offset(1, 0), .Offset(1 + UBound(result, 1), 0)) = Application.WorksheetFunction.Transpose(result)
        End With
    Next src
End Sub

언급URL : https://stackoverflow.com/questions/8560718/split-comma-separated-entries-to-new-rows